function plt(args)

stlp=subwrd(args,1)
if (stlp='-h')
  say ' '
  say '  Plots the Pressure Increment of the Layers for the Reference Case csvm'
  say ' '
  say ' Usage:'
  say ' pltdel [stlp] [stl]'
  say ' '
  say ' Default:'
  say ' stlp = yes ; stl=A'
  say ' '
  say ' No Arguments'
  say ' stlp : to put (yes) or not (no) the label A, B at the figures'
  say ' stl1 : label : A, B'
  say ' '
  say ' Must be runned under grads -p (portrait)'
  say ' '
  return
endif
* To put (yes) or Not (no) the label A, B, C ... at the figures.
if (stlp='') ; stlp='yes' ; endif
* To put label for the figure if equal capital letter: A, B
stl=subwrd(args,2)
if (stl='') ; stl='A' ; endif

rec=chkmdpt()
if (rec!=0)
  return
endif

* Getting Kmax (number of pressure levels) and csvm (reference case)
'run ../../Config/Case_Dates.gs 'MONAN' 1 'ZCAS' 'no
filecsdt='./Case_Dates.dgs'
rec=read(filecsdt)
lrec=sublin(rec,2)
Kmax=subwrd(lrec,1)
csvm=subwrd(lrec,5)
rec=close(filecsdt)
'!rm -f 'filecsdt
if (Kmax < 100)
  _ResVer='L0'Kmax
else
  _ResVer='L'Kmax
endif

fcg='dir.cfg'
rec=read(fcg)
lrec=sublin(rec,1)
lrec=sublin(rec,2)
diri=subwrd(lrec,1)
rec=read(fcg)
lrec=sublin(rec,2)
_dirfig=subwrd(lrec,1)%'png_'csvm'/'
rec=close(fcg)

filei='Vertical_Standards_'csvm'.'_ResVer'.ctl'

say ' '
say '  diri = 'diri
say ' filei = 'filei
say ' '

'reinit'

dfilei=diri''filei
rec=chkopfl(dfilei)
if (rec!=0)
  return
endif

'open 'dfilei

'set warn off'
'display min(del,z=1,z='Kmax')'
dmn=subwrd(result,4)
'display max(del,z=1,z='Kmax')'
dmx=subwrd(result,4)
vrga=0
vrgb=55
xli=5
say ' '
say ' del min = 'dmn'  vrga = 'vrga
say ' del max = 'dmx'  vrgb = 'vrgb'  xli = 'xli
say ' '

'set display color white'
'clear'

'set grads off'
'set xlopts 1 8 0.15'
'set ylopts 1 8 0.15'
'set cthick 8'
'set xlint 'xli
'set vrange 'vrga' 'vrgb
'display del'

'draw title `1Pressure Increment\`1Case : 'csvm' - 'Kmax' Layers'
'draw xlab `3D`1p (hPa)'
'draw ylab `1Pressure (hPa)'

'query gxinfo'
lx=sublin(result,3)
ly=sublin(result,4)
xa=subwrd(lx,4)
xb=subwrd(lx,6)
ya=subwrd(ly,4)
yb=subwrd(ly,6)

if (stlp='yes')
  xr=xb-0.5
  yr=yb-0.5
  xs=xb-0.25
  ys=yb-0.25
  'set line 0 1 6'
  'draw recf 'xr' 'yr' 'xb' 'yb
  'set line 1 1 6'
  'draw rec 'xr' 'yr' 'xb' 'yb
  'set string 1 c 6 0'
  'set strsiz 0.175'
  'draw string 'xs' 'ys' `1'stl
endif

strz=0.175
ds=2.0*strz
xra=xa
xrb=xra+12.5*strz
dy=3.0*ds+2.0*strz
ym=0.5*(ya+yb)
yrb=ym+0.3*dy
yra=ym-0.3*dy
ysn=yrb-1.25*strz
ysx=yra+1.25*strz
xs=0.5*(xra+xrb)
'set line 0 1 6'
'draw recf 'xra' 'yra' 'xrb' 'yrb
'set line 1 1 6'
'draw rec 'xra' 'yra' 'xrb' 'yrb
'set strsiz 'strz
'set string 1 c 6'
'draw string 'xs' 'ysn' `3D`1pMin='dmn
'draw string 'xs' 'ysx' `3D`1pMax='dmx

figname='Pressure_Increment_'csvm'_'_ResVer'.png'
say ' 'figname
say ' '
fig=_dirfig''figname
'printim 'fig' png white'

return

function chkmdpt()
'query gxinfo'
lm=sublin(result,2)
xb=subwrd(lm,4)
yb=subwrd(lm,6)
rec=0
if (yb < xb)
  say ' '
  say ' Error: must use grads -p (portrait)'
  say ' '
  rec=1
endif
return rec

function chkopfl(file)
res=read(file)
rec=sublin(res,1)
if (rec=0)
   lrec=sublin(res,2)
   dst=subwrd(lrec,1)
   if (dst!='dset') ; rec=1 ; endif
endif
if (rec!=0)
  say ' '
  say ' Error : 'file' does not exist or is not a ctl file'
  say ' '
endif
if (rec=0)
  res=close(file)
endif
return rec